怎么同步开关状态 顺便分享小爱同学+app控制继电器代码

weekend

Creeper666 发表于 2020-2-26 09:06
根据小爱的值返回状态需要使用心跳包才可以，否则状态只会在按下按钮后才返回 ...

[mw_shl_code=arduino,true]void heartbeat()
{
   if (oState)
    { Button1.print("on");
    }
    else
    {
    Button1.print("off");
    }
}[/mw_shl_code]

在setup里注册一个 Blinker.attachHeartbeat(heartbeat);  回调函数 ， 然后加上上面的代码可以同步开关状态你试下，如果有好的办法请回复我一下

asker

weekend 发表于 2020-2-27 00:01
[mw_shl_code=arduino,true]void heartbeat()
{
   if (oState)

编译可以通过 理论上应该没问题 心跳包里直接判断state的值是不行的 我是自己自定义了一个变量用来储存开关状态 然后用心跳包发送 不过你这个方法更好 不用再多设置一个变量

一入极客深似海

你好楼主，你的帖子我已经看完了。知道你已经将程序改好。不知能否你提供你已修改好的源代码？[感激]

z01228

一入极客深似海 发表于 2020-3-2 16:24
你好楼主，你的帖子我已经看完了。知道你已经将程序改好。不知能否你提供你已修改好的源代码？[感激] ...

https://www.arduino.cn/thread-94564-1-1.html

z01228

可以看下我的帖子

asker

一入极客深似海 发表于 2020-3-2 16:24
你好楼主，你的帖子我已经看完了。知道你已经将程序改好。不知能否你提供你已修改好的源代码？[感激] ...

[mw_shl_code=arduino,true]#define BLINKER_WIFI
#define BLINKER_MIOT_OUTLET

#include <Blinker.h>

char auth[] = "";     

#define LED 0    //0对应GPIO0  2对应GPIO2

bool oState = false;

// 新建组件对象
BlinkerButton Button1("btn-abc");

//按下按键即会执行该函数
void button1_callback(const String & state)
{
  BLINKER_LOG("get button state: ", state);

  if (state == BLINKER_CMD_ON) {
    digitalWrite(LED, LOW);
    oState = true;
  } else if (state == BLINKER_CMD_OFF) {
    digitalWrite(LED, HIGH);
    oState = false;
  }
  Button1.print(state);
  BlinkerMIOT.powerState(oState ? "on" : "off");
  BlinkerMIOT.print();
}

//用于小爱同学控制
void miotPowerState(const String & state)
{
    BLINKER_LOG("need set power state: ", state);

    if (state == BLINKER_CMD_ON) {
        digitalWrite(LED, LOW);
        BlinkerMIOT.powerState("on");   //反馈电源状态
        Button1.print("on");
        BlinkerMIOT.print();    //将以上属性发送出去
        oState = true;
    }
    else if (state == BLINKER_CMD_OFF) {
        digitalWrite(LED, HIGH);
        BlinkerMIOT.powerState("off");  //反馈电源状态
        Button1.print("off");
        BlinkerMIOT.print();    //将以上数据发送出去
        oState = false;
    }
}

//Miot问询
void miotQuery(int32_t queryCode)
{
    BLINKER_LOG("MIOT Query codes: ", queryCode);

    switch (queryCode)
    {
        case BLINKER_CMD_QUERY_ALL_NUMBER :
            BLINKER_LOG("MIOT Query All");
            BlinkerMIOT.powerState(oState ? "on" : "off");
            BlinkerMIOT.print();
            break;
        case BLINKER_CMD_QUERY_POWERSTATE_NUMBER :
            BLINKER_LOG("MIOT Query Power State");
            BlinkerMIOT.powerState(oState ? "on" : "off");
            BlinkerMIOT.print();
            break;
        default :
            BlinkerMIOT.powerState(oState ? "on" : "off");
            BlinkerMIOT.print();
            break;
    }
}

void dataRead(const String & data)
{
    BLINKER_LOG("Blinker readString: ", data);
    Blinker.vibrate();
    uint32_t BlinkerTime = millis();
    Blinker.print("millis", BlinkerTime);
}

void heartbeat()
{
   if (oState) {
    Button1.print("on");
    }else {
    Button1.print("off");
    }
}

//配网
void smartConfig()
{
     WiFi.mode(WIFI_STA);
     Serial.println("Wait for Smartconfig");
     Blinker.delay(500);   // 等待配网
     WiFi.beginSmartConfig();
     while (1){
     Blinker.delay(200);
     if (WiFi.smartConfigDone()){
     Serial.println("SmartConfig Success");
     WiFi.setAutoConnect(true);  // 设置自动连接
     break;
     }
   }
}

void setup()
{
    //初始化串口
    Serial.begin(115200);
    BLINKER_DEBUG.stream(Serial);
    pinMode(LED, OUTPUT);
    digitalWrite(LED, HIGH);

    smartConfig();
    while (WiFi.status() != WL_CONNECTED)
    {
     Serial.print("..");
     Blinker.delay(300);
    }
   
    Serial.println("WiFi connected");  
    Blinker.begin(auth, WiFi.SSID().c_str(),WiFi.psk().c_str());
    Blinker.attachData(dataRead);
    Button1.attach(button1_callback);

    BlinkerMIOT.attachPowerState(miotPowerState);
    BlinkerMIOT.attachQuery(miotQuery);
    Blinker.attachHeartbeat(heartbeat);  //注册心跳函数回调
}

void loop()
{
    Blinker.run();
} [/mw_shl_code]

z01228 那位兄弟的也不错

一入极客深似海

asker 发表于 2020-3-5 21:31
[mw_shl_code=arduino,true]#define BLINKER_WIFI
#define BLINKER_MIOT_OUTLET

感谢你，

evokezys

Creeper666 发表于 2020-2-25 20:47
不是if (state == "on")是[/ba ...

请问一下“on”和BLINKER_CMD_ON有什么不同吗

Creeper666

evokezys 发表于 2020-3-23 09:39
请问一下“on”和BLINKER_CMD_ON有什么不同吗

楼主的on是小爱同学控制反馈的，blinker_cmd_on是app控制反馈

wenbin1717

asker 发表于 2020-3-5 21:31
[mw_shl_code=arduino,true]#define BLINKER_WIFI
#define BLINKER_MIOT_OUTLET

大佬，这个自动配网有点问题啊，我刷写进去后，每次断电都需要重新配网，这个不能记住原来配过的网吗，上电直接连接。