Arduino抓取NTP的日期信息

平行的默

看了很多帖子，关于获取时分秒很清楚了。但好像没有获取年月日时信息。这部分有哪个库文件可以解决吗？
谢谢各位

topdog

给你一个ESP32的程序：
[pre]#include <WiFi.h>
#include "time.h"

const char* ssid       = "WiFi名称";
const char* password   = "WiFi密码";

const char* ntpServer = "pool.ntp.org";
const long  gmtOffset_sec = 28800;
const int   daylightOffset_sec = 0;

void printLocalTime()
{
  struct tm timeinfo;
  if (!getLocalTime(&timeinfo)) {
    Serial.println("Failed to obtain time");
    return;
  }
  Serial.println(&timeinfo, "%A, %Y-%m-%d %H:%M:%S");
}

void setup()
{
  Serial.begin(115200);

  //connect to WiFi
  Serial.printf("Connecting to %s ", ssid);
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" CONNECTED");

  //init and get the time
  configTime(gmtOffset_sec, daylightOffset_sec, ntpServer);
  printLocalTime();

  //disconnect WiFi as it's no longer needed
  WiFi.disconnect(true);
  WiFi.mode(WIFI_OFF);
}

void loop()
{
  delay(1000);
  printLocalTime();
}[/pre]
效果图：

平行的默

太感谢了。看起来用了time.h，我试试。