读取BME280数据（气压、海拔、温湿、湿度）

coloz

[md]# BME280
BME280是一款气压传感器，因附带有温湿度传感器，让其显得很超值。

## 硬件&接入方式
开发板使用esp8266开发板，接入方式为WiFi接入
BME280支持SPI和IIC两种模式，本示例使用IIC驱动，传感器连接到开发板IIC接口即可  

## 驱动库(两个都需要装)
https://github.com/adafruit/Adafruit_BME280_Library
https://github.com/adafruit/Adafruit_Sensor

## 示例程序
```
#define BLINKER_WIFI

#include <Blinker.h>

char auth[] = "Your Device Secret Key";
char ssid[] = "Your WiFi network SSID or name";
char pswd[] = "Your WiFi network WPA password or WEP key";

BlinkerNumber TEMP("temp"); // Temperature
BlinkerNumber PRES("pres"); // Pressure
BlinkerNumber ALTI("alti"); // Altitude
BlinkerNumber HUMI("humi"); // Humidity

// Download Adafruit-BMP085-Library library here:
// https://github.com/adafruit/Adafruit_BME280_Library  
// https://github.com/adafruit/Adafruit_Sensor
#include <Wire.h>
#include <Adafruit_Sensor.h>
#include <Adafruit_BME280.h>

#define SEALEVELPRESSURE_HPA (1013.25)

Adafruit_BME280 bme;

void dataRead(const String & data)
{
    BLINKER_LOG("Blinker readString: ", data);

    Blinker.vibrate();

    uint32_t BlinkerTime = millis();

    Blinker.print("millis", BlinkerTime);
}

void heartbeat()
{
    TEMP.print(bme.readTemperature());
    HUMI.print(bme.readHumidity());
    PRES.print(bme.readPressure());
    ALTI.print(bme.readAltitude(SEALEVELPRESSURE_HPA));
}

void setup()
{
    Serial.begin(115200);
    BLINKER_DEBUG.stream(Serial);

    pinMode(LED_BUILTIN, OUTPUT);
    digitalWrite(LED_BUILTIN, LOW);

    Blinker.begin(auth, ssid, pswd);
    Blinker.attachData(dataRead);
    Blinker.attachHeartbeat(heartbeat);

    if (!bme.begin()) {
        BLINKER_LOG("Could not find a valid BME280 sensor, check wiring!");
        while (1) {delay(100);}
    }
}

void loop()
{
    Blinker.run();
}
```[/md]

ecstart

有空做一个看看！再加个本地屏幕就更完美了1

花西子

我想问下，NodeMcu的IIC引脚是哪两个

liuchengqi1017

花西子 发表于 2019-11-24 15:01
我想问下，NodeMcu的IIC引脚是哪两个

D1,和D2吧

mr7

提个问题，由于手头的OLED也是IIC占用D1，D2的，请问如何能做到用OLED与BME280错开接入开发板的脚位？并显示BME280数据？

奈何col

mr7 发表于 2020-4-26 01:33
提个问题，由于手头的OLED也是IIC占用D1，D2的，请问如何能做到用OLED与BME280错开接入开发板的脚位？并显 ...

iic可以接很多设备，通过地址选择控制不同的设备

mr7

奈何col 发表于 2020-4-26 09:34
iic可以接很多设备，通过地址选择控制不同的设备

谢谢，解答。